@PACKAGE_INIT@

# Partial path copied from build variable OPENMP_INSTALL_LIBDIR
set( openmp_LIB_DIR "@OPENMP_INSTALL_LIBDIR@" )

# Full path to libomp.so using PACKAGE_PREFIX_DIR and OPENMP_INSTALL_LIBDIR partial path.
set_and_check( openmp_LIB_INSTALL_DIR "@PACKAGE_OPENMP_INSTALL_LIBDIR@" )

# Full path to omp.h using PACKAGE_PREFIX and LIBOMP_HEADERS_INSTALL_PATH partial path.
set_and_check( openmp_INCLUDE_DIR "@PACKAGE_LIBOMP_HEADERS_INSTALL_PATH@" )
set_and_check( openmp_INCLUDE_DIRS "${openmp_INCLUDE_DIR}" )

set( libomp_install_rpath "@LIBOMP_INSTALL_RPATH@" )
include( "${CMAKE_CURRENT_LIST_DIR}/openmpTargets.cmake" )

set_property(TARGET OpenMP::omp APPEND PROPERTY
    INTERFACE_COMPILE_OPTIONS "-fopenmp"
)
set_property(TARGET OpenMP::omp APPEND PROPERTY
    INTERFACE_LINK_OPTIONS "-fopenmp"
)

if(CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND libomp_install_rpath)
  set_property(TARGET OpenMP::omp APPEND PROPERTY
      INTERFACE_LINK_OPTIONS "-fno-openmp-implicit-rpath"
  )
endif()

foreach(lang IN ITEMS C CXX Fortran)
  if(NOT TARGET OpenMP::OpenMP_${lang})
    add_library(OpenMP::OpenMP_${lang} INTERFACE IMPORTED GLOBAL)
    set_target_properties(OpenMP::OpenMP_${lang} PROPERTIES
      INTERFACE_LINK_LIBRARIES OpenMP::omp
    )
  endif()
  set(OpenMP_${lang}_FOUND TRUE)
  set(OpenMP_${lang}_FLAGS "-fopenmp")
  set(OpenMP_${lang}_LIB_NAMES "omp")
endforeach()

set(OpenMP_FOUND TRUE)