# MIT License
#
# Copyright (c) 2023-2025 Advanced Micro Devices, Inc. All rights reserved.
#
# Permission is hereby granted, free of charge, to any person obtaining a copy
# of this software and associated documentation files (the "Software"), to deal
# in the Software without restriction, including without limitation the rights
# to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
# copies of the Software, and to permit persons to whom the Software is
# furnished to do so, subject to the following conditions:
#
# The above copyright notice and this permission notice shall be included in all
# copies or substantial portions of the Software.
#
# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
# OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
# SOFTWARE.

rocprofiler_activate_clang_tidy()

add_library(rocprofiler-sdk-rocattach-shared-library SHARED)

foreach(_NAMESPACE rocprofiler-sdk rocprofiler-sdk-rocattach)
    foreach(_ALIAS library shared-library)
        add_library(${_NAMESPACE}::rocprofiler-sdk-rocattach-${_ALIAS} ALIAS
                    rocprofiler-sdk-rocattach-shared-library)
    endforeach()
endforeach()

target_sources(
    rocprofiler-sdk-rocattach-shared-library
    PRIVATE rocattach.cpp auxv.cpp ptrace_runner.cpp ptrace_session.cpp symbol_lookup.cpp)
add_subdirectory(common)

target_include_directories(
    rocprofiler-sdk-rocattach-shared-library
    INTERFACE $<BUILD_INTERFACE:${PROJECT_BINARY_DIR}/source/include>
              $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/source/include>
              $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>)

target_link_libraries(
    rocprofiler-sdk-rocattach-shared-library
    PRIVATE rocprofiler-sdk::rocprofiler-sdk-shared-library
            rocprofiler-sdk::rocprofiler-sdk-headers
            rocprofiler-sdk::rocprofiler-sdk-build-flags
            rocprofiler-sdk::rocprofiler-sdk-common-library
            rocprofiler-sdk::rocprofiler-sdk-cereal)

set_target_properties(
    rocprofiler-sdk-rocattach-shared-library
    PROPERTIES OUTPUT_NAME rocprofiler-sdk-rocattach
               LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/${CMAKE_INSTALL_LIBDIR}
               SOVERSION ${PROJECT_VERSION_MAJOR}
               VERSION ${PROJECT_VERSION}
               SKIP_BUILD_RPATH OFF
               BUILD_RPATH "\$ORIGIN"
               INSTALL_RPATH "\$ORIGIN"
               DEFINE_SYMBOL ROCATTACH_EXPORTS)

install(
    TARGETS rocprofiler-sdk-rocattach-shared-library
    DESTINATION ${CMAKE_INSTALL_LIBDIR}
    COMPONENT rocattach
    EXPORT rocprofiler-sdk-rocattach-targets)