derek.holloway
7502bf64a4
CodeQL / Analyze (actions) (push) Canceled after 0s
CodeQL / Analyze (python) (push) Canceled after 0s
pre-commit / pre-commit (push) Canceled after 0s
Multi-Arch CI / setup (push) Canceled after 0s
Publish build_manylinux_x86_64 images / publish_build_manylinux_x86_64 (push) Canceled after 0s
Setup (Multi-Arch) / setup (push) Canceled after 0s
Multi-Arch CI / Linux::${{ fromJSON(needs.setup.outputs.linux_build_config || '{}').build_variant_label || 'skip' }} (push) Canceled after 0s
Publish TheRock Docker image / build-and-push-image (push) Canceled after 0s
Publish no_rocm_image_ubi10 image / publish_no_rocm_image_ubi10 (push) Canceled after 0s
Multi-Arch CI / Windows::${{ fromJSON(needs.setup.outputs.windows_build_config || '{}').build_variant_label || 'skip' }} (push) Canceled after 0s
Publish TheRock Docker image / build-and-push-image (push) Canceled after 0s
Multi-Arch CI / Manifest Diff (push) Canceled after 0s
TheRock Manifest Diff Report / Generate Manifest Diff Report (push) Canceled after 0s
Multi-Arch CI / CI Summary (push) Canceled after 0s
Publish no_rocm_image_ubuntu24_04 images / publish_no_rocm_image_ubuntu24_04 (push) Canceled after 0s
Publish no_rocm_image_ubuntu24_04_ocl_rt images / publish_no_rocm_image_ubuntu24_04_ocl_rt (push) Canceled after 0s
Publish TheRock Docker image / build-and-push-image (push) Canceled after 0s
Publish TheRock Docker image / build-and-push-image (push) Canceled after 0s
Publish no_rocm_image_ubuntu24_04 images / publish_no_rocm_image_ubuntu24_04_rocgdb (push) Canceled after 0s
Publish no_rocm_image_ubuntu24_04_rocgdb images / publish_no_rocm_image_ubuntu24_04_rocgdb (push) Canceled after 0s
Publish no_rocm_image_ubuntu24_04 images / publish_no_rocm_image_ubuntu24_04_ocl_rt (push) Canceled after 0s
Publish TheRock Docker image / build-and-push-image (push) Canceled after 0s
Unit Tests / Unit Tests :: ubuntu-24.04 (push) Canceled after 0s
Unit Tests / Unit Tests :: windows-2022 (push) Canceled after 0s
Publish no_rocm_image_ubuntu24_04 images / publish_no_rocm_image_ubuntu24_04_media (push) Canceled after 0s
Unit Tests / Unit Tests Summary (push) Canceled after 0s
Publish no_rocm_image_ubuntu24_04 images / publish_no_rocm_image_ubuntu24_04_openmpi (push) Canceled after 0s
98 lines
2.7 KiB
CMake
98 lines
2.7 KiB
CMake
set(LLVM_TARGET_DEFINITIONS LLGSOptions.td)
|
|
tablegen(LLVM LLGSOptions.inc -gen-opt-parser-defs)
|
|
add_public_tablegen_target(LLGSOptionsTableGen)
|
|
|
|
set(LLVM_TARGET_DEFINITIONS PlatformOptions.td)
|
|
tablegen(LLVM PlatformOptions.inc -gen-opt-parser-defs)
|
|
add_public_tablegen_target(PlatformOptionsTableGen)
|
|
|
|
set(LLDB_PLUGINS)
|
|
|
|
if(CMAKE_SYSTEM_NAME MATCHES "Linux|Android")
|
|
list(APPEND LLDB_PLUGINS lldbPluginProcessLinux)
|
|
endif()
|
|
|
|
if(CMAKE_SYSTEM_NAME MATCHES "AIX")
|
|
list(APPEND LLDB_PLUGINS lldbPluginProcessAIX)
|
|
endif()
|
|
|
|
if(CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
|
|
list(APPEND LLDB_PLUGINS lldbPluginProcessFreeBSD)
|
|
endif()
|
|
|
|
if(CMAKE_SYSTEM_NAME MATCHES "NetBSD")
|
|
list(APPEND LLDB_PLUGINS lldbPluginProcessNetBSD)
|
|
endif()
|
|
|
|
if(CMAKE_SYSTEM_NAME MATCHES "Darwin")
|
|
list(APPEND LLDB_PLUGINS lldbPluginObjectFileMachO)
|
|
elseif(CMAKE_SYSTEM_NAME MATCHES "Windows")
|
|
list(APPEND LLDB_PLUGINS lldbPluginObjectFilePECOFF)
|
|
elseif(CMAKE_SYSTEM_NAME MATCHES "AIX")
|
|
list(APPEND LLDB_PLUGINS lldbPluginObjectFileXCOFF)
|
|
else()
|
|
list(APPEND LLDB_PLUGINS lldbPluginObjectFileELF)
|
|
endif()
|
|
|
|
option(LLDB_ENABLE_MOCK_ACCELERATOR_PLUGIN
|
|
"Enable the mock accelerator plugin in lldb-server. This compiles the plugin \
|
|
into the lldb-server binary and enables the associated tests. When enabled, \
|
|
lldb-server will advertise accelerator-plugins+ in qSupported." OFF)
|
|
|
|
add_subdirectory(Plugins)
|
|
|
|
set(LLDB_SERVER_PLUGINS)
|
|
|
|
if(LLDB_ENABLE_MOCK_ACCELERATOR_PLUGIN)
|
|
list(APPEND LLDB_SERVER_PLUGINS lldbServerPluginMockAccelerator)
|
|
endif()
|
|
|
|
if(APPLE_EMBEDDED)
|
|
if(LLDB_CODESIGN_IDENTITY)
|
|
# Use explicit LLDB identity
|
|
set(LLVM_CODESIGNING_IDENTITY ${LLDB_CODESIGN_IDENTITY})
|
|
else()
|
|
# Use explicit LLVM identity or default to lldb_codesign if empty
|
|
if(NOT LLVM_CODESIGNING_IDENTITY)
|
|
set(LLVM_CODESIGNING_IDENTITY lldb_codesign)
|
|
endif()
|
|
endif()
|
|
endif()
|
|
|
|
add_lldb_tool(lldb-server
|
|
lldb-gdbserver.cpp
|
|
lldb-platform.cpp
|
|
lldb-server.cpp
|
|
LLDBServerUtilities.cpp
|
|
SystemInitializerLLGS.cpp
|
|
|
|
LINK_COMPONENTS
|
|
Option
|
|
Support
|
|
LINK_LIBS
|
|
lldbHost
|
|
lldbInitialization
|
|
lldbVersion
|
|
${LLDB_PLUGINS}
|
|
${LLDB_SERVER_PLUGINS}
|
|
lldbPluginInstructionARM
|
|
lldbPluginInstructionLoongArch
|
|
lldbPluginInstructionMIPS
|
|
lldbPluginInstructionMIPS64
|
|
lldbPluginInstructionRISCV
|
|
${LLDB_SYSTEM_LIBS}
|
|
)
|
|
|
|
add_dependencies(lldb-server
|
|
LLGSOptionsTableGen
|
|
PlatformOptionsTableGen
|
|
${tablegen_deps}
|
|
)
|
|
target_include_directories(lldb-server PRIVATE "${LLDB_SOURCE_DIR}/source")
|
|
target_link_libraries(lldb-server PRIVATE ${LLDB_SYSTEM_LIBS})
|
|
|
|
if(LLDB_ENABLE_MOCK_ACCELERATOR_PLUGIN)
|
|
target_compile_definitions(lldb-server
|
|
PRIVATE LLDB_ENABLE_MOCK_ACCELERATOR_PLUGIN)
|
|
endif()
|