derek.holloway
7502bf64a4
CodeQL / Analyze (actions) (push) Canceled after 0s
CodeQL / Analyze (python) (push) Canceled after 0s
pre-commit / pre-commit (push) Canceled after 0s
Multi-Arch CI / setup (push) Canceled after 0s
Publish build_manylinux_x86_64 images / publish_build_manylinux_x86_64 (push) Canceled after 0s
Setup (Multi-Arch) / setup (push) Canceled after 0s
Multi-Arch CI / Linux::${{ fromJSON(needs.setup.outputs.linux_build_config || '{}').build_variant_label || 'skip' }} (push) Canceled after 0s
Publish TheRock Docker image / build-and-push-image (push) Canceled after 0s
Publish no_rocm_image_ubi10 image / publish_no_rocm_image_ubi10 (push) Canceled after 0s
Multi-Arch CI / Windows::${{ fromJSON(needs.setup.outputs.windows_build_config || '{}').build_variant_label || 'skip' }} (push) Canceled after 0s
Publish TheRock Docker image / build-and-push-image (push) Canceled after 0s
Multi-Arch CI / Manifest Diff (push) Canceled after 0s
TheRock Manifest Diff Report / Generate Manifest Diff Report (push) Canceled after 0s
Multi-Arch CI / CI Summary (push) Canceled after 0s
Publish no_rocm_image_ubuntu24_04 images / publish_no_rocm_image_ubuntu24_04 (push) Canceled after 0s
Publish no_rocm_image_ubuntu24_04_ocl_rt images / publish_no_rocm_image_ubuntu24_04_ocl_rt (push) Canceled after 0s
Publish TheRock Docker image / build-and-push-image (push) Canceled after 0s
Publish TheRock Docker image / build-and-push-image (push) Canceled after 0s
Publish no_rocm_image_ubuntu24_04 images / publish_no_rocm_image_ubuntu24_04_rocgdb (push) Canceled after 0s
Publish no_rocm_image_ubuntu24_04_rocgdb images / publish_no_rocm_image_ubuntu24_04_rocgdb (push) Canceled after 0s
Publish no_rocm_image_ubuntu24_04 images / publish_no_rocm_image_ubuntu24_04_ocl_rt (push) Canceled after 0s
Publish TheRock Docker image / build-and-push-image (push) Canceled after 0s
Unit Tests / Unit Tests :: ubuntu-24.04 (push) Canceled after 0s
Unit Tests / Unit Tests :: windows-2022 (push) Canceled after 0s
Publish no_rocm_image_ubuntu24_04 images / publish_no_rocm_image_ubuntu24_04_media (push) Canceled after 0s
Unit Tests / Unit Tests Summary (push) Canceled after 0s
Publish no_rocm_image_ubuntu24_04 images / publish_no_rocm_image_ubuntu24_04_openmpi (push) Canceled after 0s
96 lines
2.4 KiB
LLVM
96 lines
2.4 KiB
LLVM
; RUN: opt < %s -passes=aa-eval -print-all-alias-modref-info 2>&1 | FileCheck %s
|
|
|
|
@c = constant [8 x i32] zeroinitializer
|
|
|
|
declare void @dummy()
|
|
|
|
declare void @foo(ptr)
|
|
|
|
; CHECK-LABEL: Function: basic
|
|
; CHECK: NoModRef: Ptr: i32* @c <-> call void @dummy()
|
|
define void @basic(ptr %p) {
|
|
call void @dummy()
|
|
load i32, ptr @c
|
|
ret void
|
|
}
|
|
|
|
; CHECK-LABEL: Function: recphi
|
|
; CHECK: NoModRef: Ptr: i32* %p <-> call void @dummy()
|
|
define void @recphi() {
|
|
entry:
|
|
br label %loop
|
|
|
|
loop:
|
|
%p = phi ptr [ @c, %entry ], [ %p.next, %loop ]
|
|
call void @dummy()
|
|
load i32, ptr %p
|
|
%p.next = getelementptr i32, ptr %p, i64 1
|
|
%c = icmp ne ptr %p.next, getelementptr (i32, ptr @c, i64 8)
|
|
br i1 %c, label %loop, label %exit
|
|
|
|
exit:
|
|
ret void
|
|
}
|
|
|
|
; Tests that readonly noalias implies !Mod.
|
|
;
|
|
; CHECK-LABEL: Function: readonly_noalias
|
|
; CHECK: Just Ref: Ptr: i32* %p <-> call void @foo(ptr %p)
|
|
define void @readonly_noalias(ptr readonly noalias %p) {
|
|
call void @foo(ptr %p)
|
|
load i32, ptr %p
|
|
ret void
|
|
}
|
|
|
|
; Tests that readnone noalias implies !Mod.
|
|
;
|
|
; CHECK-LABEL: Function: readnone_noalias
|
|
; CHECK: Just Ref: Ptr: i32* %p <-> call void @foo(ptr %p)
|
|
define void @readnone_noalias(ptr readnone noalias %p) {
|
|
call void @foo(ptr %p)
|
|
load i32, ptr %p
|
|
ret void
|
|
}
|
|
|
|
; Tests that writeonly noalias doesn't imply !Ref (since it's still possible
|
|
; to read from the object through other pointers if the pointer wasn't
|
|
; written).
|
|
;
|
|
; CHECK-LABEL: Function: writeonly_noalias
|
|
; CHECK: Both ModRef: Ptr: i32* %p <-> call void @foo(ptr %p)
|
|
define void @writeonly_noalias(ptr writeonly noalias %p) {
|
|
call void @foo(ptr %p)
|
|
load i32, ptr %p
|
|
ret void
|
|
}
|
|
|
|
; Tests that readonly doesn't imply !Mod without noalias.
|
|
;
|
|
; CHECK-LABEL: Function: just_readonly
|
|
; CHECK: Both ModRef: Ptr: i32* %p <-> call void @foo(ptr %p)
|
|
define void @just_readonly(ptr readonly %p) {
|
|
call void @foo(ptr %p)
|
|
load i32, ptr %p
|
|
ret void
|
|
}
|
|
|
|
; Tests that readnone doesn't imply !Mod without noalias.
|
|
;
|
|
; CHECK-LABEL: Function: just_readnone
|
|
; CHECK: Both ModRef: Ptr: i32* %p <-> call void @foo(ptr %p)
|
|
define void @just_readnone(ptr readnone %p) {
|
|
call void @foo(ptr %p)
|
|
load i32, ptr %p
|
|
ret void
|
|
}
|
|
|
|
; Tests that writeonly doesn't imply !Ref.
|
|
;
|
|
; CHECK-LABEL: Function: just_writeonly
|
|
; CHECK: Both ModRef: Ptr: i32* %p <-> call void @foo(ptr %p)
|
|
define void @just_writeonly(ptr writeonly %p) {
|
|
call void @foo(ptr %p)
|
|
load i32, ptr %p
|
|
ret void
|
|
}
|