derek/TheRock
1
0 Fork 0
Code Issues Pull Requests Actions 1 Packages Projects Releases Wiki Activity
Files
1a182e2dac58879f215c0fad0f5f78c76dcafe56
TheRock/compiler/amd-llvm/llvm/test/Transforms/LoopInterchange/profitability-instorder.ll
T
derek.holloway 7502bf64a4
CodeQL / Analyze (actions) (push) Canceled after 0s
Details
CodeQL / Analyze (python) (push) Canceled after 0s
Details
pre-commit / pre-commit (push) Canceled after 0s
Details
Multi-Arch CI / setup (push) Canceled after 0s
Details
Publish build_manylinux_x86_64 images / publish_build_manylinux_x86_64 (push) Canceled after 0s
Details
Setup (Multi-Arch) / setup (push) Canceled after 0s
Details
Multi-Arch CI / Linux::${{ fromJSON(needs.setup.outputs.linux_build_config || '{}').build_variant_label || 'skip' }} (push) Canceled after 0s
Details
Publish TheRock Docker image / build-and-push-image (push) Canceled after 0s
Details
Publish no_rocm_image_ubi10 image / publish_no_rocm_image_ubi10 (push) Canceled after 0s
Details
Multi-Arch CI / Windows::${{ fromJSON(needs.setup.outputs.windows_build_config || '{}').build_variant_label || 'skip' }} (push) Canceled after 0s
Details
Publish TheRock Docker image / build-and-push-image (push) Canceled after 0s
Details
Multi-Arch CI / Manifest Diff (push) Canceled after 0s
Details
TheRock Manifest Diff Report / Generate Manifest Diff Report (push) Canceled after 0s
Details
Multi-Arch CI / CI Summary (push) Canceled after 0s
Details
Publish no_rocm_image_ubuntu24_04 images / publish_no_rocm_image_ubuntu24_04 (push) Canceled after 0s
Details
Publish no_rocm_image_ubuntu24_04_ocl_rt images / publish_no_rocm_image_ubuntu24_04_ocl_rt (push) Canceled after 0s
Details
Publish TheRock Docker image / build-and-push-image (push) Canceled after 0s
Details
Publish TheRock Docker image / build-and-push-image (push) Canceled after 0s
Details
Publish no_rocm_image_ubuntu24_04 images / publish_no_rocm_image_ubuntu24_04_rocgdb (push) Canceled after 0s
Details
Publish no_rocm_image_ubuntu24_04_rocgdb images / publish_no_rocm_image_ubuntu24_04_rocgdb (push) Canceled after 0s
Details
Publish no_rocm_image_ubuntu24_04 images / publish_no_rocm_image_ubuntu24_04_ocl_rt (push) Canceled after 0s
Details
Publish TheRock Docker image / build-and-push-image (push) Canceled after 0s
Details
Unit Tests / Unit Tests :: ubuntu-24.04 (push) Canceled after 0s
Details
Unit Tests / Unit Tests :: windows-2022 (push) Canceled after 0s
Details
Publish no_rocm_image_ubuntu24_04 images / publish_no_rocm_image_ubuntu24_04_media (push) Canceled after 0s
Details
Unit Tests / Unit Tests Summary (push) Canceled after 0s
Details
Publish no_rocm_image_ubuntu24_04 images / publish_no_rocm_image_ubuntu24_04_openmpi (push) Canceled after 0s
Details
Flatten subprojects into a single base monorepo
2026-09-02 16:34:47 -07:00

265 lines
10 KiB
LLVM
Raw Blame History

; NOTE: Assertions have been autogenerated by utils/update_test_checks.py UTC_ARGS: --version 6
; RUN: opt < %s -passes=loop-interchange -loop-interchange-profitabilities=instorder -S | FileCheck %s
; for (i = 0; i < 10; i++)
; for (j = 0; j < 10; j++)
; A[i + 100*j] = 0;
;
; The above loop should be interchanged in terms of locality of reference.
;
define void @profitable(ptr %A) {
; CHECK-LABEL: define void @profitable(
; CHECK-SAME: ptr [[A:%.*]]) {
; CHECK-NEXT: [[LOOP_J_PREHEADER:.*:]]
; CHECK-NEXT: br label %[[LOOP_J:.*]]
; CHECK: [[LOOP_I_HEADER_PREHEADER1:.*]]:
; CHECK-NEXT: br label %[[LOOP_I_HEADER_PREHEADER:.*]]
; CHECK: [[LOOP_I_HEADER_PREHEADER]]:
; CHECK-NEXT: [[I:%.*]] = phi i64 [ [[I_INC:%.*]], %[[LOOP_I_LATCH:.*]] ], [ 0, %[[LOOP_I_HEADER_PREHEADER1]] ]
; CHECK-NEXT: br label %[[LOOP_J_SPLIT1:.*]]
; CHECK: [[LOOP_J]]:
; CHECK-NEXT: br label %[[LOOP_J1:.*]]
; CHECK: [[LOOP_J1]]:
; CHECK-NEXT: [[J:%.*]] = phi i64 [ [[TMP2:%.*]], %[[LOOP_J_SPLIT:.*]] ], [ 0, %[[LOOP_J]] ]
; CHECK-NEXT: br label %[[LOOP_I_HEADER_PREHEADER1]]
; CHECK: [[LOOP_J_SPLIT1]]:
; CHECK-NEXT: [[MUL:%.*]] = mul i64 [[J]], 100
; CHECK-NEXT: [[OFFSET:%.*]] = add i64 [[I]], [[MUL]]
; CHECK-NEXT: [[GEP:%.*]] = getelementptr inbounds i8, ptr [[A]], i64 [[OFFSET]]
; CHECK-NEXT: store i8 0, ptr [[GEP]], align 1
; CHECK-NEXT: [[TMP0:%.*]] = add i64 [[J]], 1
; CHECK-NEXT: [[TMP1:%.*]] = icmp eq i64 [[TMP0]], 10
; CHECK-NEXT: br label %[[LOOP_I_LATCH]]
; CHECK: [[LOOP_J_SPLIT]]:
; CHECK-NEXT: [[TMP2]] = add i64 [[J]], 1
; CHECK-NEXT: [[TMP3:%.*]] = icmp eq i64 [[TMP2]], 10
; CHECK-NEXT: br i1 [[TMP3]], label %[[EXIT:.*]], label %[[LOOP_J1]]
; CHECK: [[LOOP_I_LATCH]]:
; CHECK-NEXT: [[I_INC]] = add i64 [[I]], 1
; CHECK-NEXT: [[EC_I:%.*]] = icmp eq i64 [[I_INC]], 10
; CHECK-NEXT: br i1 [[EC_I]], label %[[LOOP_J_SPLIT]], label %[[LOOP_I_HEADER_PREHEADER]]
; CHECK: [[EXIT]]:
; CHECK-NEXT: ret void
;
entry:
br label %loop.i.header
loop.i.header:
%i = phi i64 [ 0, %entry ], [ %i.inc, %loop.i.latch ]
br label %loop.j
loop.j:
%j = phi i64 [ 0, %loop.i.header ], [ %j.inc, %loop.j ]
%mul = mul i64 %j, 100
%offset = add i64 %i, %mul
%gep = getelementptr inbounds i8, ptr %A, i64 %offset
store i8 0, ptr %gep
%j.inc = add i64 %j, 1
%ec.j = icmp eq i64 %j.inc, 10
br i1 %ec.j, label %loop.i.latch, label %loop.j
loop.i.latch:
%i.inc = add i64 %i, 1
%ec.i = icmp eq i64 %i.inc, 10
br i1 %ec.i, label %exit, label %loop.i.header
exit:
ret void
}
; for (i = 0; i < 10; i++)
; for (j = 0; j < 10; j++)
; A[i + 100*(9-j)] = 0;
;
; The above loop should be interchanged in terms of locality of reference.
;
define void @profitable_neg_step(ptr %A) {
; CHECK-LABEL: define void @profitable_neg_step(
; CHECK-SAME: ptr [[A:%.*]]) {
; CHECK-NEXT: [[LOOP_J_PREHEADER:.*:]]
; CHECK-NEXT: br label %[[LOOP_J:.*]]
; CHECK: [[LOOP_I_HEADER_PREHEADER1:.*]]:
; CHECK-NEXT: br label %[[LOOP_I_HEADER_PREHEADER:.*]]
; CHECK: [[LOOP_I_HEADER_PREHEADER]]:
; CHECK-NEXT: [[I:%.*]] = phi i64 [ [[I_INC:%.*]], %[[LOOP_I_LATCH:.*]] ], [ 0, %[[LOOP_I_HEADER_PREHEADER1]] ]
; CHECK-NEXT: br label %[[LOOP_J_SPLIT1:.*]]
; CHECK: [[LOOP_J]]:
; CHECK-NEXT: br label %[[LOOP_J1:.*]]
; CHECK: [[LOOP_J1]]:
; CHECK-NEXT: [[J:%.*]] = phi i64 [ [[TMP2:%.*]], %[[LOOP_J_SPLIT:.*]] ], [ 0, %[[LOOP_J]] ]
; CHECK-NEXT: br label %[[LOOP_I_HEADER_PREHEADER1]]
; CHECK: [[LOOP_J_SPLIT1]]:
; CHECK-NEXT: [[J_REV:%.*]] = sub i64 9, [[J]]
; CHECK-NEXT: [[MUL:%.*]] = mul i64 [[J_REV]], 100
; CHECK-NEXT: [[OFFSET:%.*]] = add i64 [[I]], [[MUL]]
; CHECK-NEXT: [[GEP:%.*]] = getelementptr inbounds i8, ptr [[A]], i64 [[OFFSET]]
; CHECK-NEXT: store i8 0, ptr [[GEP]], align 1
; CHECK-NEXT: [[TMP0:%.*]] = add i64 [[J]], 1
; CHECK-NEXT: [[TMP1:%.*]] = icmp eq i64 [[TMP0]], 10
; CHECK-NEXT: br label %[[LOOP_I_LATCH]]
; CHECK: [[LOOP_J_SPLIT]]:
; CHECK-NEXT: [[TMP2]] = add i64 [[J]], 1
; CHECK-NEXT: [[TMP3:%.*]] = icmp eq i64 [[TMP2]], 10
; CHECK-NEXT: br i1 [[TMP3]], label %[[EXIT:.*]], label %[[LOOP_J1]]
; CHECK: [[LOOP_I_LATCH]]:
; CHECK-NEXT: [[I_INC]] = add i64 [[I]], 1
; CHECK-NEXT: [[EC_I:%.*]] = icmp eq i64 [[I_INC]], 10
; CHECK-NEXT: br i1 [[EC_I]], label %[[LOOP_J_SPLIT]], label %[[LOOP_I_HEADER_PREHEADER]]
; CHECK: [[EXIT]]:
; CHECK-NEXT: ret void
;
entry:
br label %loop.i.header
loop.i.header:
%i = phi i64 [ 0, %entry ], [ %i.inc, %loop.i.latch ]
br label %loop.j
loop.j:
%j = phi i64 [ 0, %loop.i.header ], [ %j.inc, %loop.j ]
%j.rev = sub i64 9, %j
%mul = mul i64 %j.rev, 100
%offset = add i64 %i, %mul
%gep = getelementptr inbounds i8, ptr %A, i64 %offset
store i8 0, ptr %gep
%j.inc = add i64 %j, 1
%ec.j = icmp eq i64 %j.inc, 10
br i1 %ec.j, label %loop.i.latch, label %loop.j
loop.i.latch:
%i.inc = add i64 %i, 1
%ec.i = icmp eq i64 %i.inc, 10
br i1 %ec.i, label %exit, label %loop.i.header
exit:
ret void
}
; for (i = 0; i < 10; i++)
; for (j = 0; j < 10; j++)
; A[100*i + j] = 0;
;
; The above loop should NOT be interchanged in terms of locality of reference.
;
define void @unprofitable0(ptr %A) {
; CHECK-LABEL: define void @unprofitable0(
; CHECK-SAME: ptr [[A:%.*]]) {
; CHECK-NEXT: [[LOOP_I_HEADER_PREHEADER:.*]]:
; CHECK-NEXT: br label %[[LOOP_I_HEADER1:.*]]
; CHECK: [[LOOP_I_HEADER1]]:
; CHECK-NEXT: [[I:%.*]] = phi i64 [ 0, %[[LOOP_I_HEADER_PREHEADER]] ], [ [[I_INC:%.*]], %[[LOOP_I_LATCH:.*]] ]
; CHECK-NEXT: [[MUL:%.*]] = mul i64 [[I]], 100
; CHECK-NEXT: br label %[[LOOP_J:.*]]
; CHECK: [[LOOP_J]]:
; CHECK-NEXT: [[J:%.*]] = phi i64 [ 0, %[[LOOP_I_HEADER1]] ], [ [[TMP0:%.*]], %[[LOOP_J]] ]
; CHECK-NEXT: [[GEP:%.*]] = getelementptr inbounds [1 x i8], ptr [[A]], i64 [[J]], i64 [[MUL]]
; CHECK-NEXT: store i8 0, ptr [[GEP]], align 1
; CHECK-NEXT: [[TMP0]] = add i64 [[J]], 1
; CHECK-NEXT: [[TMP1:%.*]] = icmp eq i64 [[TMP0]], 10
; CHECK-NEXT: br i1 [[TMP1]], label %[[LOOP_I_LATCH]], label %[[LOOP_J]]
; CHECK: [[LOOP_I_LATCH]]:
; CHECK-NEXT: [[I_INC]] = add i64 [[I]], 1
; CHECK-NEXT: [[EC_I:%.*]] = icmp eq i64 [[I_INC]], 10
; CHECK-NEXT: br i1 [[EC_I]], label %[[LOOP_J_SPLIT:.*]], label %[[LOOP_I_HEADER1]]
; CHECK: [[LOOP_J_SPLIT]]:
; CHECK-NEXT: ret void
;
entry:
br label %loop.i.header
loop.i.header:
%i = phi i64 [ 0, %entry ], [ %i.inc, %loop.i.latch ]
%mul = mul i64 %i, 100
br label %loop.j
loop.j:
%j = phi i64 [ 0, %loop.i.header ], [ %j.inc, %loop.j ]
%gep = getelementptr inbounds [1 x i8], ptr %A, i64 %j, i64 %mul
store i8 0, ptr %gep
%j.inc = add i64 %j, 1
%ec.j = icmp eq i64 %j.inc, 10
br i1 %ec.j, label %loop.i.latch, label %loop.j
loop.i.latch:
%i.inc = add i64 %i, 1
%ec.i = icmp eq i64 %i.inc, 10
br i1 %ec.i, label %exit, label %loop.i.header
exit:
ret void
}
; for (i = 0; i < 42; i++)
; for (j = 0; j < 42; j++)
; A[100*i + j] = B[100*i + j] + C[i + 100*j] + C[i + 99*j] + C[i + 98*j];
;
; The above loop should NOT be interchanged in terms of locality of reference.
;
define void @unprofitable1(ptr noalias %A, ptr noalias %B, ptr noalias %C) {
; CHECK-LABEL: define void @unprofitable1(
; CHECK-SAME: ptr noalias [[A:%.*]], ptr noalias [[B:%.*]], ptr noalias [[C:%.*]]) {
; CHECK-NEXT: [[LOOP_J_PREHEADER:.*]]:
; CHECK-NEXT: br label %[[LOOP_J:.*]]
; CHECK: [[LOOP_J]]:
; CHECK-NEXT: [[I:%.*]] = phi i64 [ 0, %[[LOOP_J_PREHEADER]] ], [ [[I_INC:%.*]], %[[LOOP_I_LATCH:.*]] ]
; CHECK-NEXT: br label %[[LOOP_I_HEADER_PREHEADER:.*]]
; CHECK: [[LOOP_I_HEADER_PREHEADER]]:
; CHECK-NEXT: [[J:%.*]] = phi i64 [ 0, %[[LOOP_J]] ], [ [[TMP0:%.*]], %[[LOOP_I_HEADER_PREHEADER]] ]
; CHECK-NEXT: [[GEP_A:%.*]] = getelementptr inbounds [100 x i8], ptr [[A]], i64 [[I]], i64 [[J]]
; CHECK-NEXT: [[GEP_B:%.*]] = getelementptr inbounds [100 x i8], ptr [[B]], i64 [[I]], i64 [[J]]
; CHECK-NEXT: [[GEP_C0:%.*]] = getelementptr inbounds [100 x i8], ptr [[C]], i64 [[J]], i64 [[I]]
; CHECK-NEXT: [[GEP_C1:%.*]] = getelementptr inbounds [99 x i8], ptr [[C]], i64 [[J]], i64 [[I]]
; CHECK-NEXT: [[GEP_C2:%.*]] = getelementptr inbounds [98 x i8], ptr [[C]], i64 [[J]], i64 [[I]]
; CHECK-NEXT: [[VAL_B:%.*]] = load i8, ptr [[GEP_B]], align 1
; CHECK-NEXT: [[VAL_C0:%.*]] = load i8, ptr [[GEP_C0]], align 1
; CHECK-NEXT: [[VAL_C1:%.*]] = load i8, ptr [[GEP_C1]], align 1
; CHECK-NEXT: [[VAL_C2:%.*]] = load i8, ptr [[GEP_C2]], align 1
; CHECK-NEXT: [[SUM_0:%.*]] = add i8 [[VAL_B]], [[VAL_C0]]
; CHECK-NEXT: [[SUM_1:%.*]] = add i8 [[SUM_0]], [[VAL_C1]]
; CHECK-NEXT: [[SUM_2:%.*]] = add i8 [[SUM_1]], [[VAL_C2]]
; CHECK-NEXT: store i8 [[SUM_2]], ptr [[GEP_A]], align 1
; CHECK-NEXT: [[TMP0]] = add i64 [[J]], 1
; CHECK-NEXT: [[TMP1:%.*]] = icmp eq i64 [[TMP0]], 42
; CHECK-NEXT: br i1 [[TMP1]], label %[[LOOP_I_LATCH]], label %[[LOOP_I_HEADER_PREHEADER]]
; CHECK: [[LOOP_I_LATCH]]:
; CHECK-NEXT: [[I_INC]] = add i64 [[I]], 1
; CHECK-NEXT: [[EC_I:%.*]] = icmp eq i64 [[I_INC]], 42
; CHECK-NEXT: br i1 [[EC_I]], label %[[EXIT:.*]], label %[[LOOP_J]]
; CHECK: [[EXIT]]:
; CHECK-NEXT: ret void
;
entry:
br label %loop.i.header
loop.i.header:
%i = phi i64 [ 0, %entry ], [ %i.inc, %loop.i.latch ]
br label %loop.j
loop.j:
%j = phi i64 [ 0, %loop.i.header ], [ %j.inc, %loop.j ]
%gep.A = getelementptr inbounds [100 x i8], ptr %A, i64 %i, i64 %j
%gep.B = getelementptr inbounds [100 x i8], ptr %B, i64 %i, i64 %j
%gep.C0 = getelementptr inbounds [100 x i8], ptr %C, i64 %j, i64 %i
%gep.C1 = getelementptr inbounds [99 x i8], ptr %C, i64 %j, i64 %i
%gep.C2 = getelementptr inbounds [98 x i8], ptr %C, i64 %j, i64 %i
%val.B = load i8, ptr %gep.B
%val.C0 = load i8, ptr %gep.C0
%val.C1 = load i8, ptr %gep.C1
%val.C2 = load i8, ptr %gep.C2
%sum.0 = add i8 %val.B, %val.C0
%sum.1 = add i8 %sum.0, %val.C1
%sum.2 = add i8 %sum.1, %val.C2
store i8 %sum.2, ptr %gep.A
%j.inc = add i64 %j, 1
%ec.j = icmp eq i64 %j.inc, 42
br i1 %ec.j, label %loop.i.latch, label %loop.j
loop.i.latch:
%i.inc = add i64 %i, 1
%ec.i = icmp eq i64 %i.inc, 42
br i1 %ec.i, label %exit, label %loop.i.header
exit:
ret void
}
Reference in new issue View Git Blame Copy Permalink