TheRock/rocm-libraries/projects/hiprand/test/CMakeLists.txt

# MIT License
#
# Copyright (c) 2023 Advanced Micro Devices, Inc. All rights reserved.
#
# Permission is hereby granted, free of charge, to any person obtaining a copy
# of this software and associated documentation files (the "Software"), to deal
# in the Software without restriction, including without limitation the rights
# to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
# copies of the Software, and to permit persons to whom the Software is
# furnished to do so, subject to the following conditions:
#
# The above copyright notice and this permission notice shall be included in all
# copies or substantial portions of the Software.
#
# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
# OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
# SOFTWARE.

# Tests

# YAML-driven CTest test categorisation for the *installed* tree only.
# The shared helper apply_ctest_category_labels(yaml, install_test_file)
# scans the install-tree CTestTestfile.cmake fragment we hand-roll
# below for `add_test()` lines and appends explicit
# set_tests_properties() lines so `ctest -L <tier>` works against the
# install tree. Build-tree tests are intentionally not labelled here
# (mirrors the rocWMMA approach).
set(_HIPRAND_TEST_CATEGORIES_YAML "${CMAKE_SOURCE_DIR}/test_categories.yaml")
set(_HIPRAND_SHARED_CTEST          "${ROCM_LIBRARIES_ROOT}/shared/ctest/TestCategories.cmake")
if(EXISTS "${_HIPRAND_SHARED_CTEST}" AND EXISTS "${_HIPRAND_TEST_CATEGORIES_YAML}")
    include("${_HIPRAND_SHARED_CTEST}")
    message(STATUS "hipRAND: YAML-based CTest categorization enabled (install tree only)")
else()
    if(NOT EXISTS "${_HIPRAND_SHARED_CTEST}")
        message(STATUS "hipRAND: shared/ctest not found at ${_HIPRAND_SHARED_CTEST}; skipping CTest categories")
    endif()
    if(NOT EXISTS "${_HIPRAND_TEST_CATEGORIES_YAML}")
        message(STATUS "hipRAND: ${_HIPRAND_TEST_CATEGORIES_YAML} not found; skipping CTest categories")
    endif()
endif()

set(PROFILE_DIR "${CMAKE_BINARY_DIR}/coverage-report")
set(INSTALL_TEST_FILE "${CMAKE_CURRENT_BINARY_DIR}/install_CTestTestfile.cmake")
file(WRITE "${INSTALL_TEST_FILE}"
[=[
# This is a test file generated by hipRAND for install time.
# It differs slightly from the default testfile, and you may encounter issues because of that.
]=]
)

function(add_relative_test test_name test_target)
    get_target_property(EXE_PATH ${test_target} RUNTIME_OUTPUT_DIRECTORY)
    if(EXE_PATH STREQUAL "EXE_PATH-NOTFOUND")
        set(EXE_PATH ".")
    endif()
    get_filename_component(EXE_PATH "${EXE_PATH}" ABSOLUTE BASE_DIR "${CMAKE_CURRENT_BINARY_DIR}")
    get_target_property(EXE_NAME ${test_target} RUNTIME_OUTPUT_NAME)
    if(EXE_NAME STREQUAL "EXE_NAME-NOTFOUND")
        get_target_property(EXE_NAME ${test_target} OUTPUT_NAME)
        if(EXE_NAME STREQUAL "EXE_NAME-NOTFOUND")
            set(EXE_NAME "${test_target}")
        endif()
    endif()
    file(RELATIVE_PATH rel_path "${CMAKE_CURRENT_BINARY_DIR}" "${EXE_PATH}/${EXE_NAME}")
    add_test(NAME "${test_name}" COMMAND "./${rel_path}")
    if(BUILD_CODE_COVERAGE)
        set_tests_properties(${test_name} PROPERTIES
            ENVIRONMENT "LLVM_PROFILE_FILE=${PROFILE_DIR}/profraw/hiprand-coverage_%m.profraw"
        )
    endif()
    file(APPEND "${INSTALL_TEST_FILE}" "add_test(${test_name} \"../${EXE_NAME}\")\n")
endfunction()

# Get hipRAND tests source files
file(GLOB hipRAND_TEST_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/test_hiprand*.cpp)

if(BUILD_CODE_COVERAGE)
  add_custom_target(
    coverage_analysis
    DEPENDS hiprand
    COMMAND echo Coverage GTEST_FILTER=\${GTEST_FILTER}
    COMMAND ${CMAKE_COMMAND} -E rm -rf ${PROFILE_DIR}
    COMMAND ${CMAKE_COMMAND} -E make_directory ${PROFILE_DIR}/profraw
    COMMAND ctest --output-on-failure --gtest_filter=\"\${GTEST_FILTER}\"
    WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
  )

  find_program(
    LLVM_PROFDATA
    llvm-profdata
    REQUIRED
    HINTS ${ROCM_PATH}/llvm/bin
    PATHS /opt/rocm/llvm/bin
  )

  find_program(
    LLVM_COV
    llvm-cov
    REQUIRED
    HINTS ${ROCM_PATH}/llvm/bin
    PATHS /opt/rocm/llvm/bin
  )

  add_custom_target(
    coverage
    DEPENDS coverage_analysis
    COMMAND ${LLVM_PROFDATA} merge -sparse ${PROFILE_DIR}/profraw/hiprand-coverage_*.profraw -o ${PROFILE_DIR}/hiprand.profdata
    COMMAND ${LLVM_COV} report -object ${CMAKE_BINARY_DIR}/library/libhiprand-d.so -instr-profile=${PROFILE_DIR}/hiprand.profdata
    COMMAND ${LLVM_COV} show -object ${CMAKE_BINARY_DIR}/library/libhiprand-d.so -instr-profile=${PROFILE_DIR}/hiprand.profdata -format=html -output-dir=${PROFILE_DIR}
    COMMAND ${LLVM_COV} export -object ${CMAKE_BINARY_DIR}/library/libhiprand-d.so -instr-profile=${PROFILE_DIR}/hiprand.profdata -format=lcov > ${PROFILE_DIR}/coverage.info
    WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
  )
endif()

# Build hipRAND tests
foreach(test_src ${hipRAND_TEST_SRCS})
    get_filename_component(test_name ${test_src} NAME_WE)
    add_executable(${test_name} ${test_src})
    # nvcc/CUDA
    if (BUILD_WITH_LIB STREQUAL "CUDA")
      set_source_files_properties(${test_name}
        PROPERTIES
          LANGUAGE CUDA
          CUDA_STANDARD 14
      )
      set(CUDA_HOST_COMPILER ${CMAKE_CXX_COMPILER})
    endif()
    target_include_directories(${test_name}
        PUBLIC
            $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/library/src>
    )
    if(TARGET GTest::GTest)
        target_link_libraries(${test_name}
            GTest::GTest
            GTest::Main
        )
    else()
        target_link_libraries(${test_name}
            GTest::gtest
            GTest::gtest_main
        )
    endif()
    if (BUILD_WITH_LIB STREQUAL "CUDA")
        target_link_libraries(${test_name}
            hiprand
            ${CUDA_curand_LIBRARY}
        )
    else()
        target_link_libraries(${test_name}
            hiprand
            roc::rocrand
            hip::device
        )
    endif()
    set_target_properties(${test_name}
        PROPERTIES
            RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/test"
    )
    add_relative_test(${test_name} ${test_name})
    if(BUILD_CODE_COVERAGE)
        set_tests_properties(${test_name} PROPERTIES
            ENVIRONMENT "LLVM_PROFILE_FILE=${PROFILE_DIR}/profraw/hiprand-coverage_%m.profraw"
        )
    endif()
    rocm_install(TARGETS ${test_name} COMPONENT tests)
    if (WIN32 AND NOT DEFINED DLLS_COPIED)
      set(DLLS_COPIED "YES")
      set(DLLS_COPIED ${DLLS_COPIED} PARENT_SCOPE)
      # for now adding in all .dll as dependency chain is not cmake based on win32
      file( GLOB third_party_dlls
      LIST_DIRECTORIES ON
      CONFIGURE_DEPENDS
      ${HIP_DIR}/bin/*.dll
      ${HIP_DIR}/bin/hipinfo.exe
      ${ROCRAND_PATH}/bin/rocrand.dll
      ${CMAKE_SOURCE_DIR}/rtest.*
      )
      foreach( file_i ${third_party_dlls})
        add_custom_command( TARGET ${test_name} POST_BUILD COMMAND ${CMAKE_COMMAND} ARGS -E copy_if_different ${file_i} ${CMAKE_BINARY_DIR}/test )
      endforeach( file_i )
    endif()

    if (BUILD_CODE_COVERAGE)
      add_dependencies(coverage_analysis ${test_name})
    endif()
endforeach()

# Fortran Wrapper Tests
if(BUILD_FORTRAN_WRAPPER)
    add_subdirectory(fortran)
endif()

# Checks for simple linkage problems
add_subdirectory(linkage)

# Bake YAML-driven category labels into the install-tree
# CTestTestfile.cmake fragment so `ctest --test-dir
# $THEROCK_BIN_DIR/hipRAND -L <tier>` works against the install tree.
# Passing the install file as the 2nd argument tells the shared helper
# to scan it for the test names already written via add_test() above
# and emit explicit set_tests_properties(... LABELS ...) lines (the
# only form ctest's script interpreter exposes through --print-labels
# / -L). Must run AFTER add_subdirectory(fortran)/add_subdirectory(linkage)
# so all add_test() lines have been appended to INSTALL_TEST_FILE.
if(COMMAND apply_ctest_category_labels)
    apply_ctest_category_labels(
        "${_HIPRAND_TEST_CATEGORIES_YAML}"
        "${INSTALL_TEST_FILE}"
    )
endif()

rocm_install(
    FILES "${INSTALL_TEST_FILE}"
    DESTINATION "${CMAKE_INSTALL_BINDIR}/${PROJECT_NAME}"
    COMPONENT tests
    RENAME "CTestTestfile.cmake"
)