TheRock/rocm-libraries/projects/miopen/cmake/ClangTidy.cmake

################################################################################
#
# MIT License
#
# Copyright (c) 2017 Advanced Micro Devices, Inc.
#
# Permission is hereby granted, free of charge, to any person obtaining a copy
# of this software and associated documentation files (the "Software"), to deal
# in the Software without restriction, including without limitation the rights
# to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
# copies of the Software, and to permit persons to whom the Software is
# furnished to do so, subject to the following conditions:
#
# The above copyright notice and this permission notice shall be included in all
# copies or substantial portions of the Software.
#
# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
# OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
# SOFTWARE.
#
################################################################################
include(CMakeParseArguments)
include(Analyzers)

get_filename_component(CLANG_TIDY_EXE_HINT "${CMAKE_CXX_COMPILER}" PATH)

find_program(CLANG_TIDY_EXE
    NAMES
        clang-tidy
        clang-tidy-5.0
        clang-tidy-4.0
        clang-tidy-3.9
        clang-tidy-3.8
        clang-tidy-3.7
        clang-tidy-3.6
        clang-tidy-3.5
    HINTS
        ${CLANG_TIDY_EXE_HINT}
    PATH_SUFFIXES
        compiler/bin
    PATHS
        /opt/rocm/llvm/bin
        /usr/local/opt/llvm/bin
)

# Query the clang-tidy executable and return its version string in VAR.
function(find_clang_tidy_version VAR)
    execute_process(COMMAND ${CLANG_TIDY_EXE} -version OUTPUT_VARIABLE VERSION_OUTPUT)
    separate_arguments(VERSION_OUTPUT_LIST NATIVE_COMMAND "${VERSION_OUTPUT}")
    list(FIND VERSION_OUTPUT_LIST "version" VERSION_INDEX)
    if(VERSION_INDEX GREATER 0)
        math(EXPR VERSION_INDEX "${VERSION_INDEX} + 1")
        list(GET VERSION_OUTPUT_LIST ${VERSION_INDEX} VERSION)
        set(${VAR} ${VERSION} PARENT_SCOPE)
    else()
        set(${VAR} "0.0" PARENT_SCOPE)
    endif()

endfunction()

if( NOT CLANG_TIDY_EXE )
    message( STATUS "Clang tidy not found" )
    set(CLANG_TIDY_VERSION "0.0")
else()
    find_clang_tidy_version(CLANG_TIDY_VERSION)
    message( STATUS "Clang tidy found: ${CLANG_TIDY_VERSION}")
endif()

set(EXTRA_CHECKS)
# There is a bug in tidy that hangs it in some cases when it encounters optional access
# It can spend 3.5h+ and timeout the CI
# It is fixed in 18.0.0 or worked around by disabling this check: bugprone-unchecked-optional-access
# https://github.com/llvm/llvm-project/issues/59492
if (CLANG_TIDY_VERSION VERSION_LESS "18.0.0")
    list(APPEND EXTRA_CHECKS -bugprone-unchecked-optional-access)
endif()

set(CMAKE_EXPORT_COMPILE_COMMANDS ON)

set(CLANG_TIDY_FIXIT_DIR ${CMAKE_BINARY_DIR}/fixits)
file(MAKE_DIRECTORY ${CLANG_TIDY_FIXIT_DIR})
set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${CLANG_TIDY_FIXIT_DIR})

# Configure clang-tidy and create the miopen-tidy analyzer targets.
macro(enable_clang_tidy)
    set(options ANALYZE_TEMPORARY_DTORS ALL)
    set(oneValueArgs HEADER_FILTER)
    set(multiValueArgs CHECKS ERRORS EXTRA_ARGS)

    cmake_parse_arguments(PARSE "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
    list(APPEND PARSE_CHECKS ${EXTRA_CHECKS})
    string(REPLACE ";" "," CLANG_TIDY_CHECKS "${PARSE_CHECKS}")
    string(REPLACE ";" "," CLANG_TIDY_ERRORS "${PARSE_ERRORS}")
    set(CLANG_TIDY_EXTRA_ARGS)
    foreach(ARG ${PARSE_EXTRA_ARGS})
        list(APPEND CLANG_TIDY_EXTRA_ARGS "-extra-arg=${ARG}")
    endforeach()

    set(CLANG_TIDY_ALL)
    if(PARSE_ALL)
        set(CLANG_TIDY_ALL ALL)
    endif()

    if (${PARSE_ANALYZE_TEMPORARY_DTORS})
        set(CLANG_TIDY_ANALYZE_TEMPORARY_DTORS "-analyze-temporary-dtors")
    endif()

    if (${CLANG_TIDY_VERSION} VERSION_LESS "3.9.0")
        set(CLANG_TIDY_ERRORS_ARG "")
    else()
        set(CLANG_TIDY_ERRORS_ARG "-warnings-as-errors='${CLANG_TIDY_ERRORS}'")
    endif()

    if (${CLANG_TIDY_VERSION} VERSION_LESS "3.9.0")
        set(CLANG_TIDY_QUIET_ARG "")
    else()
        set(CLANG_TIDY_QUIET_ARG "-quiet")
    endif()

    if(PARSE_HEADER_FILTER)
        string(REPLACE "$" "$$" CLANG_TIDY_HEADER_FILTER "${PARSE_HEADER_FILTER}")
    else()
        set(CLANG_TIDY_HEADER_FILTER ".*")
    endif()

    set(CLANG_TIDY_COMMAND
        ${CLANG_TIDY_EXE}
        ${CLANG_TIDY_QUIET_ARG}
        -p ${CMAKE_BINARY_DIR}
        -checks='${CLANG_TIDY_CHECKS}'
        ${CLANG_TIDY_ERRORS_ARG}
        ${CLANG_TIDY_EXTRA_ARGS}
        ${CLANG_TIDY_ANALYZE_TEMPORARY_DTORS}
        -header-filter='${CLANG_TIDY_HEADER_FILTER}'
        # Uncomment next line to save fixts in the fixits/ directory under the build directory.
        # You can apply them by /opt/rocm/llvm/bin/clang-apply-replacements fixits/
        # -fix-errors
    )
    # Project-prefixed tidy targets avoid collisions with sibling projects when
    # MIOpen is included via add_subdirectory in a superbuild. Unprefixed
    # aliases are only created in standalone builds for back-compat.
    add_custom_target(miopen-tidy ${CLANG_TIDY_ALL} COMMENT "Aggregate target for clang-tidy checks")
    mark_as_analyzer(miopen-tidy)
    add_custom_target(miopen-tidy-base COMMENT "Base setup target for clang-tidy checks")
    add_custom_target(miopen-tidy-make-fixit-dir COMMAND ${CMAKE_COMMAND} -E make_directory ${CLANG_TIDY_FIXIT_DIR} COMMENT "Creating clang-tidy fixit directory")
    add_custom_target(miopen-tidy-rm-fixit-dir COMMAND ${CMAKE_COMMAND} -E remove_directory ${CLANG_TIDY_FIXIT_DIR} COMMENT "Removing clang-tidy fixit directory")
    add_dependencies(miopen-tidy-make-fixit-dir miopen-tidy-rm-fixit-dir)
    add_dependencies(miopen-tidy-base miopen-tidy-make-fixit-dir)

    if(NOT ROCM_LIBS_SUPERBUILD)
        add_custom_target(tidy DEPENDS miopen-tidy COMMENT "Back-compat alias for miopen-tidy")
        add_custom_target(tidy-base DEPENDS miopen-tidy-base COMMENT "Back-compat alias for miopen-tidy-base")
        add_custom_target(tidy-make-fixit-dir DEPENDS miopen-tidy-make-fixit-dir COMMENT "Back-compat alias for miopen-tidy-make-fixit-dir")
        add_custom_target(tidy-rm-fixit-dir DEPENDS miopen-tidy-rm-fixit-dir COMMENT "Back-compat alias for miopen-tidy-rm-fixit-dir")
    endif()
endmacro()

# Add a per-source clang-tidy check target for every source file of TARGET.
function(clang_tidy_check TARGET)
    get_target_property(SOURCES ${TARGET} SOURCES)
    # TODO: Use generator expressions instead
    # COMMAND ${CLANG_TIDY_COMMAND} $<TARGET_PROPERTY:${TARGET},SOURCES>
    # COMMAND ${CLANG_TIDY_COMMAND} $<JOIN:$<TARGET_PROPERTY:${TARGET},SOURCES>, >
    foreach(SOURCE ${SOURCES})
        if((NOT "${SOURCE}" MATCHES "(h|hpp|hxx)$") AND (NOT "${SOURCE}" MATCHES "TARGET_OBJECTS"))
            string(MAKE_C_IDENTIFIER "${SOURCE}" tidy_file)
            set(tidy_target tidy-target-${TARGET}-${tidy_file})
            add_custom_target(${tidy_target}
                DEPENDS ${SOURCE}
                COMMAND ${CLANG_TIDY_COMMAND} "-config-file=${PROJECT_SOURCE_DIR}/.clang-tidy" ${SOURCE} "-export-fixes=${CLANG_TIDY_FIXIT_DIR}/${TARGET}-${tidy_file}.yaml"
                WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
                COMMENT "clang-tidy: Running clang-tidy on target ${SOURCE}..."
            )
            add_dependencies(${tidy_target} ${TARGET})
            add_dependencies(${tidy_target} miopen-tidy-base)
            add_dependencies(miopen-tidy ${tidy_target})
        endif()
    endforeach()
endfunction()